ATNEL tech-forum

Re: Programowanie PC innaczej.

2016-05-14T14:36:47+01:00

PROTON napisał(a):

Żeby uruchomić program trzeba go wgrać do zerowego sektora dysietki lub pendrive a następnie zabootować z tego urządzenia komputer.

1. czy na realnym prawdziwym komputerze tez sie uruchomi czy tylko na maszynie wirtualnej
sprawdzałeś ?

2. Jak wgrac pod zerowy sektor pendriva ?

Statystyki: Napisane przez robertomic — 14 maja 2016, o 14:36

Re: Programowanie PC innaczej.

2015-10-08T13:15:55+01:00

Skąd czerpać informacje o przerwaniach?
Ze strony: http://www.cs.cmu.edu/~ralf/files.html , są tam pliki zawierające opisy przerwań. Dla przykładu podam jak odczytać godzinę z zegara na płycie głównej (RTC).

W pliku INTERRUP.D, pochodzącym z w/w strony znajduje się zapis:
[syntax=c]--------B-1A02-------------------------------
INT 1A - TIME - GET REAL-TIME CLOCK TIME (AT,XT286,PS)
AH = 02h
CF clear to avoid bug (see below)
Return: CF clear if successful
CH = hour (BCD)
CL = minutes (BCD)
DH = seconds (BCD)
DL = daylight savings flag (00h standard time, 01h daylight time)
CF set on error (i.e. clock not running or in middle of update)
Notes:this function is also supported by the Sperry PC, which predates the
IBM AT; the data is returned in binary rather than BCD on the Sperry,
and DL is always 00h
MS-DOS/PC DOS IO.SYS/IBMBIO.COM use this function to detect if a RTC
is preset by checking if the returned values are non-zero. If they
are, this function is called one more time, before it is assumed
that no RTC is present.
BUG:some BIOSes leave CF unchanged if successful, so CF should be cleared
before calling this function
SeeAlso: AH=00h,AH=03h,AH=04h,INT 21/AH=2Ch[/syntax]

Zgodnie z powyższym opisem po wykonaniu instrukcji:
[syntax=asm]mov ah, 0x2
int 1ah[/syntax]

W rejestrze CH mamy godzinę, w CL minuty, w DH sekundy. Wszytko w kodzie BCD więc bardzo łatwe do wyświetlenia.

W przypadku odczytu daty, w tym samym pliku INTERRUP.D mamy opis jak ją odczytać:
[syntax=c]--------B-1A04-------------------------------
INT 1A - TIME - GET REAL-TIME CLOCK DATE (AT,XT286,PS)
AH = 04h
CF clear to avoid bug (see below)
Return: CF clear if successful
CH = century (BCD)
CL = year (BCD)
DH = month (BCD)
DL = day (BCD)
CF set on error[/syntax]

Statystyki: Napisane przez PROTON — 8 paź 2015, o 13:15

Re: Programowanie PC innaczej.

2015-10-07T20:03:23+01:00

Quote:

Kompilascja Netwide Assemblerem, tworzy ona obraz dyskietki.

nasm zegar.asm -o zegar.img

Np tak ....

Statystyki: Napisane przez SunRiver — 7 paź 2015, o 20:03

Re: Programowanie PC innaczej.

2015-10-07T20:01:12+01:00

Ciekawy temat,

podpowiesz jak skompilować ten kod?

Statystyki: Napisane przez vaffanculo — 7 paź 2015, o 20:01

Programowanie PC innaczej.

2015-10-07T18:31:40+01:00

Programy na PC uruchamia się zazwyczaj pod kontrolą jakiegoś systemu operacyjniego, np. może być to DOS, Windows, Linux, itp. Można też uruchomić bezpośrenio na komputerze.
Wymagania są takie, że program musi być napisany w trybie 16bitowym, ponieważ będzie uruchamiany na procesorze pracyjącym w trybie rzeczywistym. Drugie wymaganie to program nie może być większy jak 512 bajtów, to ograniczenie wynika z tego że BIOS komputera jest w stanie wczytać tylko jeden 512 bajtów sektor i go uruchomić.
Żeby uruchomić program trzeba go wgrać do zerowego sektora dysietki lub pendrive a następnie zabootować z tego urządzenia komputer.

O to program zegar.asm

[syntax=asm][bits 16]
[org 0x7c00]
start:

jmp word 0:code

;ES:DI - adres VRAM
;B800:0000 - początek - tryb tekstowy

code:
mov ax, 0xb800
mov es, ax
xor di, di
mov ds, di
xor ax, ax
mov cx, 80*25
cld
rep stosw;fill CX words at ES:DI with AX
mov di, (80*12+40-6)*2
mov si, text
mov cx, text_dl
write:
movsb; mov byte DS:SI -> ES:DI
mov al,12
stosb;store AL at address ES:DI
loop write

czas:
;#######################################
;odczyt godziny (tryb BCD)
clc
xor ax, ax
xor bx, bx
xor cx, cx
xor dx, dx
mov ah, 0x2
int 1ah

;przetwarzanie godziny
;godzina
xor ax, ax
mov al, ch
shr al, 4
add al, "0"
mov [data], al

mov al, ch
and al, 0b00001111
add al, "0"
mov [data+1], al

mov al,":"
mov [data+2], al

;minuta
mov al, cl
shr al, 4
add al, "0"
mov [data+3], al

mov al, cl
and al, 0b00001111
add al, "0"
mov [data+4], al

mov al,":"
mov [data+5], al

;sekunda
mov al, dh
shr al, 4
add al, "0"
mov [data+6], al

mov al, dh
and al, 0b00001111
add al, "0"
mov [data+7], al

mov al, " "
mov [data+8], al
mov [data+9], al

;wypisanie godziny
mov di, (80*13+40-4)*2
mov si, data
mov cx, data_dl
write2:
movsb
mov al, 4
stosb
loop write2

;#########################################
;odczyt daty
clc
xor ax, ax
xor bx, bx
xor cx, cx
xor dx, dx
mov ah, 0x4
int 1ah

;przetwarzanie daty
;century
xor ax, ax
mov al, ch
shr al, 4
add al, "0"
mov [data], al

mov al, ch
and al, 0b00001111
add al, "0"
mov [data+1], al

;rok
mov al, cl
shr al, 4
add al, "0"
mov [data+2], al

mov al, cl
and al, 0b00001111
add al, "0"
mov [data+3], al

mov al,"-"
mov [data+4], al

;miesiac
mov al, dh
shr al, 4
add al, "0"
mov [data+5], al

mov al, dh
and al, 0b00001111
add al, "0"
mov [data+6], al

mov al,"-"
mov [data+7], al

;dzien
mov al, dl
shr al, 4
add al, "0"
mov [data+8], al

mov al, dl
and al, 0b00001111
add al, "0"
mov [data+9], al

;wypisanie godziny
mov di, (80*14+40-5)*2
mov si, data
mov cx, data_dl
write3:
movsb
mov al, 6
stosb
loop write3

;czekanie na klawisz
;xor ax, ax
;int 16h

jmp czas

; stop
jmp $

text db "ZEGAR PROTON"
text_dl equ $ - text
data times 10 db " "
data_dl equ $ - data

; botesctor

times (510-($-start)) db 0
db 0x55, 0xAA
times ((1440*1024)-($-start)) db 0[/syntax]

Kompilascja Netwide Assemblerem, tworzy ona obraz dyskietki.

nasm zegar.asm -o zegar.img

Efekt działania programu pod VirtualBoxem

Porgram powstał na bazie artykułów z miesięcznika programista, "Bliżej krzemu"

Statystyki: Napisane przez PROTON — 7 paź 2015, o 18:31