ATNEL tech-forum 2019-08-19T15:42:17+01:00 https://forum.atnel.pl/feed.php?f=47&t=22361&mode 2019-08-19T15:42:17+01:00 2019-08-19T15:42:17+01:00 https://forum.atnel.pl/viewtopic.php?t=22361&p=221402#p221402 <![CDATA[Re: Usypianie arduino i watchdog]]> radex324 napisał(a):

Witam, czy mógłby mi ktoś wyjaśnić czy da się tak zaprogramować watchdog aby działał razem z usypianiem procesora?

Da, ale WDT będzie co pewien czas resetował lub budził albo budził po czy resetował CPU.

radex324 napisał(a):

Zaś jeżeli zmienię na " WDTCSR |= 1<<WDE | 1<< WDIE; " to wykonuje się przerwanie i jak ma wykonać się drugie to procesor się restartuje.

Normalne zachowanie, pierwsze przepełnienie licznika wywołuje przerwanie, drugie wywołuje reset.

Statystyki: Napisane przez Semi — 19 sie 2019, o 15:42

]]> 2019-06-23T20:42:38+01:00 2019-06-23T20:42:38+01:00 https://forum.atnel.pl/viewtopic.php?t=22361&p=219943#p219943 <![CDATA[Usypianie arduino i watchdog]]> [syntax=c]/*
* Sketch for testing sleep mode with wake up on WDT.
* Donal Morrissey - 2011.
*
*/
#include <avr/sleep.h>
#include <avr/power.h>
#include <avr/wdt.h>

#define LED_PIN (13)

volatile int f_wdt=1;



/***************************************************
* Name: ISR(WDT_vect)
*
* Returns: Nothing.
*
* Parameters: None.
*
* Description: Watchdog Interrupt Service. This
* is executed when watchdog timed out.
*
***************************************************/
ISR(WDT_vect)
{
if(f_wdt == 0)
{
f_wdt=1;
}
else
{
Serial.println("WDT Overrun!!!");
}
}


/***************************************************
* Name: enterSleep
*
* Returns: Nothing.
*
* Parameters: None.
*
* Description: Enters the arduino into sleep mode.
*
***************************************************/
void enterSleep(void)
{
set_sleep_mode(SLEEP_MODE_PWR_SAVE); /* EDIT: could also use SLEEP_MODE_PWR_DOWN for lowest power consumption. */
sleep_enable();

/* Now enter sleep mode. */
sleep_mode();

/* The program will continue from here after the WDT timeout*/
sleep_disable(); /* First thing to do is disable sleep. */

/* Re-enable the peripherals. */
power_all_enable();
}



/***************************************************
* Name: setup
*
* Returns: Nothing.
*
* Parameters: None.
*
* Description: Setup for the serial comms and the
* Watch dog timeout.
*
***************************************************/
void setup()
{
Serial.begin(9600);
Serial.println("Initialising...");
delay(100); //Allow for serial print to complete.

pinMode(LED_PIN,OUTPUT);

/*** Setup the WDT ***/

/* Clear the reset flag. */
MCUSR &= ~(1<<WDRF);

/* In order to change WDE or the prescaler, we need to
* set WDCE (This will allow updates for 4 clock cycles).
*/
WDTCSR |= (1<<WDCE) | (1<<WDE);

/* set new watchdog timeout prescaler value */
WDTCSR = 1<<WDP0 | 1<<WDP3; /* 8.0 seconds */

/* Enable the WD interrupt (note no reset). */
WDTCSR |= _BV(WDIE);

Serial.println("Initialisation complete.");
delay(100); //Allow for serial print to complete.
}



/***************************************************
* Name: enterSleep
*
* Returns: Nothing.
*
* Parameters: None.
*
* Description: Main application loop.
*
***************************************************/
void loop()
{
if(f_wdt == 1)
{
/* Toggle the LED */
digitalWrite(LED_PIN, !digitalRead(LED_PIN));

/* Don't forget to clear the flag. */
f_wdt = 0;

/* Re-enter sleep mode. */
enterSleep();
}
else
{
/* Do nothing. */
}
}[/syntax] Zaś jeżeli zmienię na " WDTCSR |= 1<<WDE | 1<< WDIE; " to wykonuje się przerwanie i jak ma wykonać się drugie to procesor się restartuje.

Statystyki: Napisane przez radex324 — 23 cze 2019, o 20:42

]]>