'This code transmits data to:
' "Simple Rx 101 using polling.Bas"
'or
' "Simple Rx 101 using interrupts.Bas"
'It is setup for 433mhZ band Rfm12Bs.
$regfile = "m328pdef.dat"
$hwstack = 40
$swstack = 40
$framesize = 40
$crystal = 8000000
$baud = 38400
Dim Spi_tx_wrd As Word
Dim Spi_tx_l As Byte At Spi_tx_wrd Overlay
Dim Spi_tx_h As Byte At Spi_tx_wrd + 1 Overlay
Dim Spi_rx_wrd As Word
Dim Spi_rx_l As Byte At Spi_rx_wrd Overlay
Dim Spi_rx_h As Byte At Spi_rx_wrd + 1 Overlay
Dim I As Byte
Dim Txbuf(18) As Byte
'These are the connections to the RFM12
'needed for this program to work.
'**** Change Alias's to match your hardware. ****
Rfm12_cs Alias Portb.2 ' D10 / SS
Config Rfm12_cs = Output
Set Rfm12_cs
Rfm12_sdi Alias Portb.3 ' D12 / MOSI
Config Rfm12_sdi = Output
Rfm12_sdo Alias Pinb.4 'D11 / MISO
Config Rfm12_sdo = Input
Set Portb.4
Rfm12_sck Alias Portb.5 'D13 / SCK
Config Rfm12_sck = Output
'*********************************
'SPI Clockrate = 4 is OK for 8mhz uC clock.
Config Spi = Hard , Interrupt = Off , Data Order = Msb , Master = Yes , _
Polarity = Low , Phase = 0 , Clockrate = 4 , Noss = 1
Spiinit
Print "Simple Tx 101"
Gosub Rfm12_init
'preload the rfm12 preamble.
Txbuf(1) = &HAA
Txbuf(2) = &HAA
Txbuf(3) = &HAA
'preload the syncron bytes.
Txbuf(4) = &H2D
Txbuf(5) = &HD4
'Your Data goes in TxBuf(6) thru TxBuf(17)
'preload some test data (12 bytes).
Txbuf(6) = "H"
Txbuf(7) = "E"
Txbuf(8) = "L"
Txbuf(9) = "L"
Txbuf(10) = "O"
Txbuf(11) = " "
Txbuf(12) = "W"
Txbuf(13) = "O"
Txbuf(14) = "R"
Txbuf(15) = "L"
Txbuf(16) = "D"
Txbuf(17) = 0 'end message with a null for use as a string in RX code.
'last byte is dummy byte.
Txbuf(18) = &HFF
Do
'wait for Tx ready.
Gosub Rfm12_ready
'print something just to show something is happening.
Print "Cos sie dzieje";
'Send TxBuf(1) thru (18).
For I = 1 To 18
'combine send command and data into one word.
Spi_tx_wrd = &HB800 + Txbuf(i)
'wait for Tx ready.
Gosub Rfm12_ready
'write one word to SPI.
'RFM12 should Tx one byte.
Gosub Rfm12_spi_wrt
Next I
Wait 1
Loop
Rfm12_ready:
'poll rfm12 sdo line till it goes high.
Reset Rfm12_cs
Bitwait Rfm12_sdo , Set
Return
Rfm12_spi_wrt:
'Send word (SPI_Tx_wrd) to RFM12.
'Also receive word (SPI_Rx_wrd).
'RFM12 Chip select
Reset Rfm12_cs
'send hi byte.
Spi_rx_h = Spimove(spi_tx_h)
'send lo byte.
Spi_rx_l = Spimove(spi_tx_l)
'deselect chip.
Set Rfm12_cs
Return
Rfm12_init:
'Initialize RFM12
Restore Init_data
For I = 1 To 10
Read Spi_tx_wrd
Print Hex(spi_tx_wrd)
'send init data to RFM12.
Gosub Rfm12_spi_wrt
'Some commands MAY need a delay
'before next command is sent.
'so just to be on the safe side.
Waitms 30
Next
Return
Init_data:
Data &H8097% '433mhz band,Enable Tx reg.
Data &H8239% 'Enable Tx, crystal osc., Synth.
Data &HA620% '435mhZ
Data &HC611% '19kbps
Data &H94A0% 'Rx settings
Data &HCED4% 'synchron pattern = D4
Data &HC4A7% 'AFC settings.
Data &H9850% 'Tx 90khz deviation.
Data &HCC17% 'PLL settings.
Data &HC2ED% 'Data Filter settings.[/syntax]
ale bez skutecznie.
Atmega skonfigurowana na wew. oscylator 8 MHz
dioda na sck miga, więc SPI chyba działa
tu są zdjęcia połączeń:
Statystyki: Napisane przez niedzwiadnl — 28 sty 2015, o 16:07
]]>
co tam jeszcze może być powodem ? .... WSZYSTKO - tylko nie ja