To niestety tylko Bascom i jedno z rozwiązań z wykorzystaniem jego naturalnych możliwości poprzez proste podstawowe polecenia jakie on udostępnia. Można by walczyć bezpośrednio na obszarach przy pomocy zmiennej w trybie OVERLAY i efekt byłby lepszy tylko same procedury bardziej rozbudowane. Niestety tu elastyczność na korzyść jeżyka C jest nieporównywalna.
Ok, czyli robimy proste działania na zmiennych tekstowych przy pomocy polecenia MID - wycinanie fragmentów tekstu) i LEN - określanie długości tekstu, STR - zamiana liczby na tekst.
Zalety rozwiązania:
- większa szybkość wyświetlania na LCD (mniej komend do wysłania = mniej czekania);
- pełna swoboda w pozycjonowaniu zmiennych (nie musi być już spacji na końcu do zamazywania zmniejszających się liczb;
- nie ma konieczności czyszczenia ekranu (po prostu nic nie drukujemy);
- aby coś pokazać na ekranie wystarczy wysyłać to odpowiednim poleceniem w pętli głównej, a w momencie zaprzestania wysyłania tekst sam zniknie (bardzo wygodne miganie);
- każdy nowy tekst napisany w miejscu już istniejącego ma priorytet i jest wyświetlany na wierzchu przez co można tworzyć ruchome warstwy lub wyświetlić chwilowy komunikat na istniejącym tle;
No i wada niestety też jest, żeby nie było za różowo
Jak wiadomo działamy na zmiennych tekstowych, a te w bascomie potrafią narobić zamieszania i zająć sporo miejsca z czym trzeba się liczyć. Zarówno sam program może nieco przybrać na wadze, jak i pojemność RAM może okazać się za mała w niektórych przypadkach. Niemniej warto chociaż przetestować możliwości.Poniższy program demonstruje działanie dwóch poleceń:
LCB Y , X , "tekst" - drukowanie na wybranej pozycji
oraz
LCB_VIEW - odświeżenie ekranu i ukazanie wszystkiego co było wywołane poprzednią instrukcją. Dopiero takie odświeżanie spowoduje że coś się wyświetli i należy to robić przynajmniej co 50-100ms stąd dobrze, żeby program był nieblokujący (najlepiej bez wait i pętli, które czekają na nic...). Oczywiście jeśli na ekranie nie wiele się dzieje to można to zrobić na żądanie w dowolnym momencie.
Uwaga aby wyświetlić jakąś zmienną numeryczną (np. zmienna temp) z dodatkami (zdefiniowane znaki, itp) należy ją zamienić najpierw na tekst przy pomocy STR() i użyć dodatkowej zmiennej tekstowej (niestety bascom nie dopuszcza podstawiania instrukcji pod zmienną) ,np:
tekst=STR(temp)+CHR(223)+"C"
i ten łańćuszek można już podstawić pod np
LCB 1 , 1 , tekst
Ok, programik wygląda tak:
[syntax=basic4gl]'-----------------------------
'-----------------------------
'
'Buforowany LCD
'
'SylwekK
'4.02.2014
'
'dostępne polecenia:
'LCB Y,X,"tekst" gdzie Y (1-2) - nr lini, X (1-16) - pozycja w lini, "tekst" - dowolna zmienna tekstowa
'LCB_VIEW wysłanie na LCD (odświeżać na końcu pętli co 50-100ms z wykorzystaniem timera programowego)
'
'Warunek prawidłowego działania: program musi być pisany jako tzw. NIEBLOKUJĄCY !!!
'
'-----------------------------
'-----------------------------
$sim 'tylko do testów, dla mikrokontrolera zakomentować !!!!!!!!
$regfile "m88def.dat"
$crystal = 8000000
$hwstack = 50
$swstack = 50
$framesize = 100
'-----------------------------
'-----------------------------
'niezbędna konfiguracja i inicjalizacja LCD
Config Lcd = 16 * 2
Config Lcdpin = Pin , Db4 = Portd.2 , Db5 = Portd.3 , Db6 = Portd.4 , Db7 = Portd.5 , E = Portd.1 , Rs = Portd.0
Cursor Off Noblink
Cls
'----
'zmienne robocze
Dim Lcdb(2) As String * 16 'Bufor lini dla LCD 16x2
Dim Strb As String * 16 'Bufor pomocniczy dla liczb i zmiennych złożonych
Dim Len_t As Byte
Dim Poz_t As Byte
Declare Sub Lcb(byval Y_t As Byte , Byval X_t As Byte , Byval Tekst_b As String * 16)
Declare Sub Lcb_view()
'-----------------------------
'-----------------------------
'zmienne dla przykładu użycia
Dim Z As Bit
Dim Zm1 As Bit
Dim Linia As Byte
Dim Px As Byte
Dim Xb As Byte
Px = 1
Linia = 1
'-----------------------------
'-----------------------------
Do
'czym niżej w programie wywołany jest tekst tym ma większy priorytet i wyświetlany jest na wierzchu
'
'
'dla lepszego zobrazowania buforowania górna linia całkowicie zapełniona jakimiś znakami
Lcb 1 , 1 , "-=o=-x-=o=-x-=o="
'poniższy tekst się będzie przesuwać
Lcb 1 , Px , "<|>"
'taka tam definicja ruchu dla obiektu
If Z = 0 Then
If Px < 14 Then Incr Px
Else
If Px > 1 Then Decr Px
End If
If Px = 14 Or Px = 1 Then Toggle Z
'wyświetlenie przykładowej zmiennej numerycznej i kodu ASCII
Strb = Str(px) + Chr(223) + "C temperatura"
Lcb 2 , 1 , Strb
'przykładowe miganie tekstem
Xb = Px Mod 2
If Xb = 0 Then Toggle Zm1
If Zm1 = 0 Then
Lcb Linia , 6 , "[MIGA]"
'dodatkowa zmiana lini migania zależna od kierunku przesuwu
If Z = 0 Then
Linia = 1
Else
Linia = 2
End If
End If
'---
'Waitms 400 'to tylko do testów i zamienić później na timer programowy !!!!!!!!!!
Lcb_view 'odświeżenie LCD (wystarczy co 50-100ms)
Loop
End
'-----------------------------
'-----------------------------
'Głowne podprogramy obsługi LCD
'-----------------------------
'-----------------------------
Sub Lcb(byval Y_t As Byte , Byval X_t As Byte , Byval Tekst_b As String * 16)
Poz_t = X_t
Len_t = Len(tekst_b)
If Y_t = 1 Or Y_t = 2 Then
Mid(lcdb(y_t) , Poz_t , Len_t) = Tekst_b
End If
End Sub
'-----------------------------
Sub Lcb_view()
Home
Lcd Lcdb(1)
Lowerline
Lcd Lcdb(2)
Lcdb(1) = Space(16)
Lcdb(2) = Space(16)
End Sub
'-----------------------------
'-----------------------------[/syntax]
Program jest dość dobrze skomentowany więc nie powinno być problemu mimo, że wygląda na nieco przydługi - to demonstracja działania zajmuje więcej
Po skompilowaniu go w takiej wersji można zobaczyć od razu efekt na symulatorze bascomowym.
Jak ktoś ma pomysły na poprawkę tego rozwiązania, (a na pewno coś by się nalazło) to oczywiście bardzo chętnie je poznam, bo to było robione tak na szybko.
Statystyki: Napisane przez SylwekK — 5 lut 2014, o 18:30
]]>
Zapewniam, że kod jest prościutki i malutki, a po bliższym zapoznaniu można zapomnieć o standardowych komendach dla LCD. Pomijam już fakt animacji na innym tekście, ale koniec ze stosowaniem spacji na końcu tekstu dla zmniejszających się wyników z większych liczb powinien nie jednego przekonać...