[syntax=basic4gl]'-----------------------------------------------------------------
'inicjalizacja procesora wstępna konfiguracja
Const Firmwareversion = "1.0.0"
$regfile = "m128def.dat"
$crystal = 16000000
'$baud = 9600
$hwstack = 64
$swstack = 10
$framesize = 40
'-----------------------------------------------------------------
'konfiguracja wyświetlacza
Config Lcd = 16 * 4
Config Lcdpin = Pin , Db4 = Porta.4 , Db5 = Porta.5 , Db6 = Porta.6 , Db7 = Porta.7 , E = Porta.3 , Rs = Porta.2
'-----------------------------------------------------------------
'konfiguracja pozostałych portów
Config Portc = Output
'Config Portb.0 = Input
'Config Portb.1 = Input
'Config Portb.2 = Input
'Config Portb.3 = Input
'Config Portb.4 = Input
Config Portd.7 = Input
Config Portb = &B11111111 : Portb = &B11111111
Portd = &B11111111
'-----------------------------------------------------------------
'konfiguracja ADC dla s-metra
Config Adc = Single , Prescaler = Auto , Reference = Avcc 'config ADC
Start Adc
'-----------------------------------------------------------------
'aliasy dla portow
'Dds_reset Alias Portd.5
Dds_fq_ud Alias Portc.4
Dds_w_clk Alias Portc.5
Dds_data Alias Portc.3
'-----------------------------------------------------------------
'konfiguracja portu szeregowego
'Config Serialin = Buffered , Size = 24 'bufor ma być na tyle duży by nie było błedów w odbiorze ramek.
'Config Input = Crlf , Echo = Crlf
'-----------------------------------------------------------------
'definicje zmiennych
Dim Freq As Long
Dim Freq_z_posrednia As Long
Dim Freq_a As Long
Dim Freq_b As Long
Dim Freqtolcd As String * 7
Dim Enc As Byte
Dim Vfo As Bit
Dim Krok As Integer
Dim Krok_a As Integer
Dim Krok_b As Integer
Dim Kierunek As Bit
Dim Modulacja As Byte
Dim Modulacja_a As Byte
Dim Modulacja_b As Byte
Dim Freq_beram As Eram Long
Dim Freq_aeram As Eram Long
Dim Krok_aeram As Eram Integer
Dim Krok_beram As Eram Integer
Dim Modulacja_aeram As Eram Byte
Dim Modulacja_beram As Eram Byte
Dim Lock_bit As Bit
Dim Ptt As Bit
Dim Konfig_bit As Bit
'zmienne dla posredniej
Dim Posrednia As Long
Dim Posredniaeram As Eram Long
Dim Posrednia_kierunek As Byte
Dim Posrednia_kierunekeram As Eram Byte
'zmienne dla ddsa
Dim Init As Byte
Dim Freqtodds As Single
Dim Freqtoddsready As Long
Dim Przelicznik As Single
Dim Przelicznik_eram As Eram Single
'zmienne scanera
Dim Scan_bit As Byte
Dim Scanspid As Byte
Dim Scantimer As Byte
Dim Scantyp As Bit
Dim Scanstop As Long
Dim Scanstop_sqech As Word
Dim Pomiar_scan As Word
Dim Squelch As Word
'zmienne Band
Dim Bandup As Long
Dim Banddown As Long
Dim Band_key As Byte
Dim Band_n As Byte
'zmienne dla posredniej
'zmienne ATT,ANT,AGC,BW,VOX,Split,Rit,Xit
Dim Att As Byte
Dim Ant As Byte
Dim Agc As Byte
Dim Bw As Byte
Dim Vox As Byte
Dim Vox_delay_gain As Byte
Dim Split_f As Long
Dim Rit As Long
Dim Xit As Long
Dim Monitor As Byte
'zmienne s-metra
Dim Char_pos As Byte
Dim Peak_pos As Byte
Dim Peak_hold As Byte
Dim Drop_hold As Byte
Dim Bar_len As Word
Dim Pomiar As Word
Dim Wynik As Word
Dim T1 As Word
'-----------------------------------------------------------------
'
Declare Sub Wyslij_f_do_dds
'-----------------------------------------------------------------
'ustawienia poczatkowe, uruchamiamy procesor
'Enable Interrupts
'Start Adc
Cursor Off
Echo Off
Cls
'-----------------------------------------------------------------
'znaki specjalne
'-----------------------------------------------------------------
' AD9850 Initialize
'Set Dds_reset : Waitus 10 : Reset Dds_reset : Waitus 10 ' Reset
Set Dds_w_clk : Waitus 10 : Reset Dds_w_clk : Waitus 10 ' W_CLK
Set Dds_fq_ud : Waitus 10 : Reset Dds_fq_ud : Waitus 10 ' FQ_UD
Init = &H00
'ladujemy ustawienia domyslne lub jesli sa to zapisane nastawy
If Freq_aeram > 1000 Then
Freq = Freq_aeram
Freq_a = Freq_aeram
Freq_b = Freq_beram
Krok = Krok_aeram
Krok_a = Krok_aeram
Krok_b = Krok_beram
Modulacja = Modulacja_aeram
Modulacja_a = Modulacja_aeram
Modulacja_b = Modulacja_beram
Posrednia = Posredniaeram
Posrednia_kierunek = Posrednia_kierunekeram 'posrednia kierunek 0-minus, 1-plus, 2-nic
Przelicznik = Przelicznik_eram
Else
Freq = 371500
Freq_a = 371500
Freq_b = 371500
Krok = 100
Krok_a = 100
Krok_b = 100
Modulacja = 2
Modulacja_a = 2
Modulacja_b = 2
Posrednia = 800000
Posrednia_kierunek = 2
Przelicznik = 343.603 'wymagana delikatna korekta w zależności od egzemplarza syntezy
End If
If Pind.1 = 0 Then
Konfig_bit = 1
End If
Cls
Gosub Wyswietlacz
If Konfig_bit = 0 Then
'-----------------------------------------------------------------
'pętla główna
Do
If Lock_bit <> 1 Then
Debounce Pinb.2 , 0 , Zmianakroku , Sub
Debounce Pind.2 , 0 , Modechange , Sub
Debounce Pind.5 , 0 , Scan , Sub
Debounce Pind.6 , 0 , Band , Sub
Debounce Pind.7 , 0 , Vfos , Sub
If Pinb.3 = 0 Then
Ptt = 1
Gosub Slupek_ptt
Else
Ptt = 0
Gosub Slupek_ptt
End If
Enc = Encoder(pinb.0 , Pinb.1 , Lewo , Prawo , 0)
End If
Debounce Pinb.4 , 0 , Lock , Sub
Loop
End If
'-------------------------------------------------------------------------------
'koniec programu
End
'-------------------------------------------------------------------------------
'-------------------------------------------------------------------------------
' wszystkie sub-programs tutaj
Plus_przelicznik:
Przelicznik = Przelicznik + 0.0001
Gosub Wyswietlacz
Return
Minus_przelicznik:
Przelicznik = Przelicznik - 0.0001
Gosub Wyswietlacz
Return
'-------------------------------------------------------------------------------
'offset posredniej
Offset:
If Posrednia_kierunek = 0 Then
Posrednia_kierunek = 1
Elseif Posrednia_kierunek = 1 Then
Posrednia_kierunek = 2
Elseif Posrednia_kierunek = 2 Then
Posrednia_kierunek = 0
End If
Gosub Wyswietlacz
Return
'-------------------------------------------------------------------------------
'blokowanie syntezy
Lock:
If Lock_bit = 0 Then
Lock_bit = 1
Else
Lock_bit = 0
End If
Gosub Wyswietlacz
Return
'-------------------------------------------------------------------------------
'galka w lewo
Lewo:
If Kierunek = 1 Then 'zabezpieczenie przeciwko przeskakiwaniu o dwa przy zmianie kierunku
Kierunek = 0
Return
End If 'galka w lewo
If Enc = 2 Or Enc = 1 Then
If Konfig_bit = 0 Then
Freq = Freq - Krok
Else
Posrednia = Posrednia - Krok
End If
End If
If Freq < 100000 And Konfig_bit = 0 Then
Freq = 3000000
End If
Gosub Freq_update
Return
'-------------------------------------------------------------------------------
'galka w prawo
Prawo:
If Kierunek = 0 Then
Kierunek = 1
Return
End If 'galka w prawo
If Enc = 3 Or Enc = 0 Then
If Konfig_bit = 0 Then
Freq = Freq + Krok
Else
Posrednia = Posrednia + Krok
End If
End If
If Freq > 3000000 And Konfig_bit = 0 Then
Freq = 100000
End If
Gosub Freq_update
Return
'split
Splitfunc:
Return
'-------------------------------------------------------------------------------
'zmiana kroku syntezy
Zmianakroku: 'zmiana kroku syntezy
If Krok = 1000 Then
Krok = 100
Elseif Krok = 100 Then
Krok = 10
Elseif Krok = 10 Then
Krok = 1
Elseif Krok = 1 Then
Krok = 1000
' Freq = Freq / 100 'kasowanie reszty przy zmianie kroku wycofalem
' Freq = Freq * 100
End If
Gosub Wyswietlacz
Return
'-------------------------------------------------------------------------------
'zmiana modulacji (dodac sterowanie pilotami)
Modechange:
If Modulacja = 1 Then
Modulacja = 2
Elseif Modulacja = 2 Then
Modulacja = 3
Elseif Modulacja = 3 Then
Modulacja = 1
End If
Gosub Wyswietlacz
Return
'-------------------------------------------------------------------------------
'sterowanie VFO
Vfos: 'zmiana vfo z A na B i modulacji
If Vfo = 1 Then
Freq_b = Freq
Freq_beram = Freq_b 'zapis ustawien do eram przeniesc do osobnej funkcji przy poweroff !!!!!!!!!!!!!!!!!!!!!!!!!!!
Freq = Freq_a
Modulacja_b = Modulacja
Modulacja_beram = Modulacja_b
Modulacja = Modulacja_a
Krok_b = Krok
Krok_beram = Krok_b
Krok = Krok_a
Vfo = 0
Elseif Vfo = 0 Then
Freq_a = Freq
Freq_aeram = Freq_a
Freq = Freq_b
Modulacja_a = Modulacja
Modulacja_aeram = Modulacja_a
Modulacja = Modulacja_b
Krok_a = Krok
Krok_aeram = Krok_a
Krok = Krok_b
Vfo = 1
End If
Posredniaeram = Posrednia
Posrednia_kierunekeram = Posrednia_kierunek
Przelicznik_eram = Przelicznik
Gosub Wyswietlacz
Return
'-------------------------------------------------------------------------------
'-------------------------------------------------------------------------------
'zmiana pasm klawiszem band
Band:
If Freq < 370000 Then
Freq = 370000
Band_n = 2
Modulacja = 2
Banddown = 350000
Bandup = 380000
Elseif Freq < 700000 Then
Freq = 700000
Band_n = 3
Modulacja = 2
Banddown = 700000
Bandup = 710000
Elseif Freq < 1010000 Then
Freq = 1010000
Band_n = 4
Modulacja = 1
Banddown = 1010000
Bandup = 1015000
Elseif Freq < 1400000 Then
Freq = 1400000
Band_n = 5
Modulacja = 3
Banddown = 1400000
Bandup = 1435000
Elseif Freq < 1800000 Then
Freq = 1806800
Band_n = 6
Modulacja = 3
Banddown = 1806800
Bandup = 1816800
Elseif Freq < 2100000 Then
Freq = 2100000
Band_n = 7
Modulacja = 3
Banddown = 2100000
Bandup = 2145000
Elseif Freq < 2480000 Then
Freq = 2489000
Band_n = 8
Modulacja = 3
Banddown = 2483000
Bandup = 2499000
Elseif Freq < 2800000 Then
Freq = 2800000
Band_n = 9
Modulacja = 3
Banddown = 2800000
Bandup = 2970000
Elseif Freq >= 2800000 Then
Freq = 181000
Band_n = 1
Modulacja = 2
Banddown = 1806800
Bandup = 1816800
End If
Gosub Wyswietlacz
Return
'-------------------------------------------------------------------------------
'obsluga zmiany czestotliwosci na wyswietlaczu
'zmienilem z przeliczania f na rzecz wyswietlania ze stringu oszczednosc kodu okolo 5%
Freq_update:
Locate 2 , 5
If Konfig_bit = 0 Then
Freqtolcd = Str(freq)
Else
Freqtolcd = Str(posrednia)
End If
If Len(freqtolcd) <= 6 Then
Freqtolcd = " " + Freqtolcd
End If
Lcd Left(freqtolcd , 2)
Lcd "."
Lcd Mid(freqtolcd , 3 , 3)
Lcd "."
Lcd Right(freqtolcd , 2)
Call Wyslij_f_do_dds 'po kazdej zmianie czestotliwosci wysylamy komende do DDS'a
Return
'-------------------------------------------------------------------------------
'obsluga zmiany wszystkiego innego na wyswietlaczu
Wyswietlacz:
Gosub Freq_update
If Konfig_bit = 0 Then
Locate 1 , 1
Lcd "VFO-"
If Vfo = 1 Then
Lcd "B"
Elseif Vfo = 0 Then
Lcd "A"
End If
Locate 2 , 1
If Modulacja = 1 Then
Lcd "CW "
Elseif Modulacja = 2 Then
Lcd "LSB"
Elseif Modulacja = 3 Then
Lcd "USB"
End If
Locate 1 , 7
If Lock_bit = 1 Then
Lcd "Lock"
Else
Lcd " "
End If
End If
Locate 1 , 12
If Krok = 1 Then
Lcd " 10Hz"
Elseif Krok = 10 Then
Lcd "100Hz"
Elseif Krok = 100 Then
Lcd " 1kHz"
Elseif Krok = 1000 Then
Lcd "10kHz"
End If
Locate 1 , 6
If Lock_bit = 1 And Scan_bit = 0 Then
Lcd " Lock "
Elseif Lock_bit = 0 And Scan_bit = 1 Then
Lcd " Scan "
'Elseif Lock_bit = 0 And Scan_bit = 0 And Memory_bit = 1 Then
Else
lcd " "
End If
Locate 4 , 1 : Lcd Lock_bit ; Scan_bit ; Konfig_bit
Return
'------------------------------------------------------------------------------
'-------------------------------------------------------------------------------
Slupek_ptt:
Deflcdchar 0 , 4 , 12 , 4 , 4 , 14 , 32 , 4 , 4 ' cyfra 1 z dolną kreską
Deflcdchar 1 , 14 , 1 , 7 , 1 , 14 , 32 , 8 , 8 ' cyfra 3 z dolną kreską
Deflcdchar 2 , 7 , 4 , 6 , 1 , 6 , 32 , 4 , 4 ' cyfra 5 z dolną kreską
Deflcdchar 3 , 15 , 1 , 2 , 4 , 8 , 32 , 8 , 8 ' cyfra 7 z dolną kreską
Deflcdchar 4 , 6 , 9 , 7 , 1 , 6 , 32 , 8 , 8 ' cyfra 9 z dolną kreską
Deflcdchar 5 , 32 , 32 , 32 , 32 , 32 , 32 , 32 , 04 ' Scale marker
Deflcdchar 6 , 27 , 27 , 27 , 27 , 27 , 27 , 27 , 32 ' bar
Deflcdchar 7 , 24 , 24 , 24 , 24 , 24 , 24 , 24 , 32 ' 1/2 left bar
If Pinb.5 = 0 Then
'a tutaj bedzie smetr z ładnymi słupkami
Locate 2 , 15
Lcd "TX"
Locate 3 , 1
Lcd "Po"
Locate 3 , 3 : Lcd Chr(0) ; Chr(5) ; Chr(5) ; Chr(5) ; Chr(5) ; Chr(5);
Locate 3 , 9 : Lcd Chr(1) ; Chr(5) ; Chr(5) ; Chr(5) ; Chr(5);
Else
Locate 2 , 15
Locate 2 , 15
Lcd "RX"
Locate 3 , 1
Lcd "S "
Locate 3 , 3 : Lcd Chr(0) ; Chr(5) ; Chr(5) ;
Locate 3 , 6 : Lcd Chr(1) ; Chr(5) ; Chr(5) ; Chr(2) ; Chr(5) ; Chr(5)
Locate 3 , 10 : Lcd Chr(5) ; Chr(5) ; Chr(3) ;
Locate 3 , 13 : Lcd Chr(5) ; Chr(5) ; Chr(4);
End If
Return
'-------------------------------------------------------------------------------
'Scanowanie częstotliwości
Scan:
If Scan_bit = 1 Then
Scan_bit = 0
Else
Scan_bit = 1
End If
Gosub Wyswietlacz
If Scan_bit = 1 Then
For Freq = Freq To Bandup Step Krok
Gosub Freq_update
'Gosub Squelch_fun
If Krok = 1 Then Waitms 50
If Krok = 10 Then Waitms 100
If Krok = 100 Then Waitms 150
If Krok = 1000 Then Waitms 200
If Pind.5 = 0 Or Squelch => 50 Then
Scanstop = Freq
Scan_bit = 0
End If
If Freq = Scanstop Then
Exit For
End If
Next Freq
End If
Return
'-------------------------------------------------------------------------------
'-------------------------------------------------------------------------------
'sterowanie DDS-em
Sub Wyslij_f_do_dds 'posrednia kierunek 0-minus, 1-plus, 2-nic
If Posrednia_kierunek = 0 Then
Freq_z_posrednia = Posrednia - Freq
Elseif Posrednia_kierunek = 1 Then
Freq_z_posrednia = Posrednia + Freq
Elseif Posrednia_kierunek = 2 Then
Freq_z_posrednia = Freq
End If
Freqtodds = Freq_z_posrednia * Przelicznik 'przelicznik ze zmiennej ladowanej z eepromu dla roznych syntez
Freqtoddsready = Freqtodds
Shiftout Dds_data , Dds_w_clk , Freqtoddsready , 3 , 32
Shiftout Dds_data , Dds_w_clk , Init , 3 , 8
Set Dds_fq_ud : Waitus 10 : Reset Dds_fq_ud : Waitus 10
End Sub[/syntax]Statystyki: Napisane przez slawek3000 — 13 paź 2013, o 16:30
]]>
