Chodzi mi oto aby podczas programowania przycisków zdalnego sterowania dodać jeszcze jeden który po zaprogramowaniu będzie podawał stan wysoki na jednym z wolnych pinów np 14. Dodam że moja wersja bascom nie potrafi poprawnie skompilować tego oryginalnego kodu. Niestety nie potrafię pisać programów na mikrokontrolery i nie mam czasu się tego uczyć ale poradzę sobie z wgraniem pliku do procka. Dlatego proszę o pomoc.
[syntax=basic4gl]$regfile = "attiny2313.dat"
$crystal = 10000000
'-----------------------------------------------------------
' konfiguracje odpowiednich portow wraz z aliasami
'wejscie ir
Ddrd.0 = 0
Portd.0 = 1
Ir Alias Pind.0
'Wejscie Programujace (int1)
Ddrd.3 = 0
Portd.3 = 1
In_prog Alias Pind.3
'Wejscie Power On / Off (int0)
Ddrd.2 = 0
Portd.2 = 1
In_pow_switch Alias Pind.2
'silnik
Ddrb.5 = 1
Silnik_lewy Alias Portb.5
Ddrb.4 = 1
Silnik_prawy Alias Portb.4
'kontrolka zasilania zielona
Ddrb.3 = 1
Zielona Alias Portb.3
Zielona = 1
'Kontrolka Zasilania Czerwona
Ddrb.6 = 1
Czerwona Alias Portb.6
Czerwona = 0
'zasilanie
Ddrb.7 = 1
Zasilanie Alias Portb.7
Zasilanie = 0
'-----------------------------------------------------------
' konfiguracja i odblokowanie przerwań
Config Timer0 = Timer , Prescale = 8
Config Timer1 = Timer , Prescale = 64
Config Int0 = Low Level
Config Int1 = Low Level
On Timer0 Ftimera
On Timer1 Zatrzymaj Nosave
On Int0 Pow_switch Nosave
On Int1 Prog Nosave
Enable Interrupts
Enable Timer0
Enable Timer1
Enable Int0
Enable Int1
Config Watchdog = 2048
'-----------------------------------------------------------
' zmienne pamieci EEPROM
Dim V_eram(37) As Eram Byte
Dim V2_eram(37) As Eram Byte
Dim V3_eram(37) As Eram Byte
Dim V_i_eram(5) As Eram Byte '0 - bajt pojedynczy, 1 - bajt podwójny
Dim V2_i_eram(5) As Eram Byte
Dim V3_i_eram(5) As Eram Byte
'----------------------------------------------------------
' zmienne pamieci RAM
Dim A(37) As Byte 'bufor dla kodu w pamięci RAM
' (bezpośredni zapis w EEPROM jest nie możliwy ze
'wzgledu na powolność zapisu w tej pamiędci)
Dim V_i(5) As Byte 'bufor dla bitow informujacych o podwojnosci bajtu
'0 - bajt pojedynczy, 1 - bajt podwójny
Dim Licznik_pom As Byte 'licznik zliczacy ilosc probek czasu na czas trwana 0 lub 1
Dim I As Byte 'zmienne "i" i "j" okreslaja pozycje w pamieci RAM i EEPROM
Dim J As Byte 'gdzie zostanie wpisana informacja czy bajt danych
'bedzie zawieral informacje podwojna czy pojedyńcza
Dim Index As Byte 'zmienna indeksuje zmienna A
Dim Zero As Byte 'zawiera informacje czy poprzednio byl impuls czy przerwa
Dim Zapis As Byte 'zmienna zawiera liczby od 0 - 3 i przy zapisie okresla
'jakiej instrukcja jest aktualnie odbierana
Dim Verified As Bit 'zawiera 1 jesli rozpoznano jaka kolwiek instrukcje
Dim Command As Byte 'zawiera numer odebranej komendy 1, 2 lub 3
Dim Bufor As Byte 'zawiera dlugosc impulsu lub przerwy wczytanej z EEPROM
Dim Bufor2 As Byte 'zawiera zakodowana informacje z pamieci EEPROM
'o podwojnosci bajtow rozkazow
'-----------------------------------------------------------
' zerowanie zmiennych uruchomienie timera 0 i przejscie do
' nieskonczonej petli
Zero = 0
Zapis = 0
Verified = 0
Start Timer0
Do
Idle
Loop
'-----------------------------------------------------------
'f-cja "zeruje" indeksy tablic
Clear_indexes:
I = 1
J = 255
Index = 0
Return
'-----------------------------------------------------------
' f-cja przesuwa indeksy o "jeden" w gore,
' znaczenia indeksow zostaly opisane przy okazji
' omawiania f-cji Zapis
Shift_indexs:
Incr J
If J = 8 Then
J = 0
Incr I
End If
Incr Index
Return
'-----------------------------------------------------------
' f-cja "zeruje" bajt danych umozliwiajac wpisanie poprawne
' nowej informacji
Clear_bajt:
A(index) = 0 'wyczysc caly bajt
V_i(i).j = 1 'udostepnij mozliwosc zapisyu dwoch malych liczb
Return
'-----------------------------------------------------------
' f-cja koduje odebrana dlugosc impulsu (lub przerwe pomiedzy
' impulsami) i zapisuje tymczasowo do pamieci RAM. Zapis i
' weryfikacja z pamiecia EEPROM trwa za dlugo i bedzie
' wykonana po odczytaniu calego rozkazu.
' - zmienna Licznik_pom zawiera dlugosc impulsu
' (lub przerwy pomiedzy impulsami)
' - tablica A(index) reprezentuje przestrzen w pamieci RAM
' do ktorej nastepuje tymczasowy zapis rozkazu
' - tablica V_i(i).j zawiera informacje czy
' bierzacy bajt z tablicy A(index) zawiera 2 krotkie
' liczby, czy jedna dluga (kazdy bit tejtablicodpwiada
' odpowiedniemu bajtowi tablicy A(index))
Zapisz:
'jesli dlugosc impulsu (lub przerwy) przekracza 16 jednostek czasu to musi on zajac caly bajt
If Licznik_pom >= 16 Then
If A(index) = 0 Then 'jesli biezacy bajt w pamieci RAM jest pusty
A(index) = Licznik_pom 'wpisz bajt
V_i(i).j = 0 'oznaczenie ze caly bajt zawiera pojedyncza liczbe
Gosub Shift_indexs 'przejdz do kolejnego bajtu
Gosub Clear_bajt 'wyczysc ten bajt
Else 'jesli biezacy bajt choc czesciowo jest zapelniony
Gosub Shift_indexs 'przejdz do nastepnego bajtu
A(index) = Licznik_pom 'zapisz zawartosc zmiennej pomocniczej do tablicy
V_i(i).j = 0 'oznacz ze cały bajt zawiera pojedyncza liczbe
Gosub Shift_indexs 'przejdz do kolejnego bajtu
Gosub Clear_bajt 'wyczysc ten bajt
End If
'jesli dlugosc impulsu (lub przerwy) NIE przekracza 16 jednostek czasu to moze on zajac tylko polowe bajtu
Else
'poniewaz jesli bajt zostaje calkowicie zapelniony to zawsze nastapuje przejscie do natepnego bajtu
'dlatego nie ma potrzeby sprawdzena bajtu na wypadek w ktorym caly bajt bylby pelny
If A(index) < 16 And A(index) > 0 Then 'jesli biezacy bajt jest czesciowo zapelniony
Shift A(index) , Left , 4 'przesuń stara czesc do gory (przesuniecie
'bierzacej zawartosci bajt o 4 pozycje w lewo)
A(index) = A(index) + Licznik_pom 'dodaj do biezacego bajtu nowa liczbe
Gosub Shift_indexs 'przejdz do kolejnego pustego bajtu
Gosub Clear_bajt
Else 'jesli caly bajt pusty
A(index) = Licznik_pom 'wpisz liczbe do bajtu
'!!! brak przejscia do kolejnego bajtu bo bajt moze pomiescic jescze jedna krotka liczbe
End If
End If
Licznik_pom = 0 'zacznij zliczanie czasu od nowa
Return
'-----------------------------------------------------------
' GLOSARIUSZ
'
' f-cja - funkcja lub procedura jezyka BASIC
' bajt - bajt tablicy A o indeksie Index (ten do ktorego
' nastepuje aktualnie zapis czasu trwania przerwy lub
' impulsu)
' pusty bajt - bajt zawierajacy wartosc 0
' bajt czesciowo zapelniony - bajt zawierajacy wartosc
' mniejsza od 16
' pelny bajt - bajt zawierajacy wartosc wieksza lub rowna 16
' krotka/mala liczba - liczba mniejsza od 16
' dluga/pojedyncza liczba - liczba wieksza lub rowna 16
Pod_porownaj:
If Bufor = A(index) Then
Verified = 1
End If
Return
Porownaj:
Gosub Pod_porownaj
Incr Bufor
Gosub Pod_porownaj
Decr Bufor
Decr Bufor
Gosub Pod_porownaj
Incr Bufor
Return
Ftimera:
Reset Watchdog
'odczyt zera
If Ir = 0 Then
If Zero = 1 Then 'zmiana stanu z 1 na 0
Gosub Zapisz ' zapis czasu trwania poprzedniej "1" do pamieci
Zero = 0 'odteraz liczy czas trwania impulsu "0"
Reset Watchdog
End If
End If
'odczyt jedynki
If Ir = 1 Then
If Zero = 0 Then 'zmiana stanu z 0 na 1
Gosub Zapisz ' zapis czasu trwania poprzedniego "0" do pamieci
Zero = 1 'odteraz liczy czas trwania impulsu "1"
Timer1 = 0 'zresetuj timer1
End If
End If
Incr Licznik_pom
'jesli odczytano choc jeden impuls to
If Licznik_pom >= 50 Or Index = 37 Then
If Index > 5 Then
If Zapis > 0 Then
For I = 1 To 37
Select Case Zapis
Case 1 : V3_eram(i) = A(i)
Stop Watchdog
Case 2 : V2_eram(i) = A(i)
Case Else : V_eram(i) = A(i)
End Select
Waitms 10
Next I
For I = 1 To 5
Select Case Zapis
Case 1 : V3_i_eram(i) = V_i(i)
Case 2 : V2_i_eram(i) = V_i(i)
Case Else : V_i_eram(i) = V_i(i)
End Select
Waitms 100
Zielona = Not Zielona
Next I
Zielona = 1
Decr Zapis
Else
Licznik_pom = Index 'ilosc odebranych sygnalow bedzie jeszcze potrzebna
For Command = 1 To 3
'I = 1
'J = 255
'Index = 0 'ustaw na poczatku
Gosub Clear_indexes
Do 'dopuki to jest dobry sprawdzaj dalej
Gosub Shift_indexs 'kolejny bajt do porownania
Verified = 0 'zakladam wstepnie ze odczytany kod jest błedny
Select Case Command
Case 3 : Bufor = V_eram(index) 'odczyt wzorca z pamieci eeprom do bufora
Bufor2 = V_i_eram(i)
Case 2 : Bufor = V2_eram(index) 'odczyt wzorca z pamieci eeprom do bufora
Bufor2 = V2_i_eram(i)
Case Else : Bufor = V3_eram(index) 'odczyt wzorca z pamieci eeprom do bufora
Bufor2 = V3_i_eram(i)
End Select
If Bufor2.j = 0 Then 'jesli to liczba pojedyncza poprostu przeprowadz porownanie
Gosub Porownaj
Else 'innaczej uwzglednij takze "podwojność" bajtu
Gosub Porownaj
Bufor = Bufor + &B00010000
Gosub Porownaj
Bufor = Bufor - &B00100000
Gosub Porownaj
End If
Loop Until Verified = 0 Or Index = Licznik_pom 'jesli jednak bajt był błedny lub sprawdzono wszystko
'to zakoncz
If Verified = 1 Then
Select Case Command
Case 1 : If Zielona = 0 Then
Silnik_prawy = 1 'pb5
End If
Silnik_lewy = 0
Start Timer1
Case 2 : If Zielona = 0 Then
Silnik_lewy = 1
End If
Silnik_prawy = 0 'pb5
Start Timer1
Case Else : Gosub Pow_switch
End Select
Exit For
End If
Next Command
End If
End If
Licznik_pom = 0
'I = 1
'J = 255
'Index = 0
Gosub Clear_indexes
End If
Return
Pow_switch:
Waitms 10
If In_pow_switch = 0 Then
Zielona = Not Zielona
Czerwona = Not Czerwona
Zasilanie = Not Zasilanie
Wait 1
End If
Return
Prog:
Waitms 10
If In_prog = 0 Then
Zielona = 1
Czerwona = 0
Zasilanie = 0
Licznik_pom = 0
'I = 1
'J = 255
'Index = 0
Gosub Clear_indexes
V_i(i).j = 0
Zero = 0
Zapis = 3
End If
Return
Zatrzymaj:
Stop Timer1
Silnik_lewy = 0
Silnik_prawy = 0 'pb5
Return[/syntax]Statystyki: Napisane przez sertyl_8009 — 29 sty 2018, o 20:40
]]>